actor NewSkullHead : Lostsoul replaces skullhead
{	
	Health 60
	SeeSound "floatskull/see"
	PainSound "floatskull/pain"
	attacksound "floatskull/attack"
	ActiveSound "floatskull/idle"
	DeathSound "floatskull/die"
	-NOICEDEATH
	-DONTFALL
	+noblooddecals
	bloodtype "CAFireBlood"
	HitObituary "%o was headbutted by a floaty skull-bastard."
	states
	{
	Death:
		TNT1 A 0
		TNT1 A 0 a_changeflag ("nogravity",1)
		SKUL F 6 Bright
		SKUL G 6 Bright A_Scream
		SKUL H 2 Bright
		SKUL I 2 Bright A_NoBlocking
		TNT1 A 0 Radius_Quake (2,10,0,20,0)
		TNT1 AAA 0 a_spawnitemex ("MonsterFire",Frandom(-20,20),Frandom(-18,18),Frandom(-18,18),Frandom(-200,200)/20.0,Frandom(-200,200)/20.0,Frandom(-200,200)/20.0,0,160)
		TNT1 A 0 A_SpawnItemEx("MonsterFireExplosion",0,0,30)
		TNT1 AAAAAAAAAAAA 0 Bright A_SpawnItemEx("MonsterFireTrail",frandom(-21,21),frandom(-21,21),frandom(-21,21),frandom(-1,1),frandom(-1,1),frandom(0,1))
		TNT1 AAAAAAAAAAA 0 Bright A_SpawnItemEx("MonsterFireEmber2",frandom(-16,16),frandom(-16,16),frandom(-16,16),frandom(-1,1),frandom(-1,1),frandom(0,1))
		TNT1 AAAAAAAAAAA 0 Bright A_SpawnItemEx("MonsterFireSmoke2",frandom(-4,4),frandom(-4,4),frandom(-4,4),frandom(-1,1),frandom(-1,1),frandom(0,1))
		TNT1 AAAAAAAAA 0 Bright A_SpawnItemEx("MonsterFireSmoke",frandom(-4,4),frandom(-4,4),frandom(-4,4),0,0,frandom(1,2))
		SKUL J 2
		SKUL K 2
		Stop
	Death.CALinkedBomb:
	Death.CALinked:
		TNT1 A 0
		TNT1 A 0 a_changeflag ("nogravity",1)
		SKUL F 6 Bright
		SKUL G 6 Bright A_Scream
		SKUL H 2 Bright A_NoBlocking
		TNT1 A 0 A_stopsound (CHAN_VOICE)
		TNT1 A 0 a_playsound ("Malefactors/LinkedHurt",0,0.80)
		TNT1 A 1 a_spawnitemex ("CALinkedKill",0,0,35)
		TNT1 A 0 a_playsound ("Malefactors/LinkedDeath",0,1,0,0.90)
		TNT1 A 2
		stop
	Death.CABladeBeam:
		TNT1 A 0
		TNT1 A 0 a_facetarget
		TNT1 A 0 a_scream
		TNT1 A 0 a_noblocking
		TNT1 A 0 a_spawnitemex ("MalefactorSkullTop",0,0,10,random(-3,3),random(-3,3),random (1,2),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_playsound ("Malefactors/BladeBeamDeath1",0,1,0,0.90)
		8DX7 B random (1,2)
		TNT1 A 0 a_nogravity
		8DX7 B 2 a_scalevelocity (0.40)
		8DX7 B 2 
		8DX7 B 2 a_scalevelocity (0.40)
		TNT1 A 0 a_stopsound (CHAN_VOICE)
		TNT1 A 0 a_stop
		8DX7 B random (36,40)
		TNT1 A 0 a_gravity
		8DX7 B 1 thrustthingz (0,1,0,0)
	HalfFalling:
		8DX7 B 1 A_JumpIf(Abs(VelZ) <= 0.01, "SlicedStop")
		loop
	SlicedStop:
		TNT1 A 0
		TNT1 AAA 0 a_spawnitemex("FireDebris",0,0,random(3,8),random(-8,8),random(-7,7),random(6,7),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_playsound ("Malefactors/BladeBeamExplosion",0,0.60,0)
		TNT1 A 1 A_SpawnItemEx("MonsterFireExplosion",0,0,30)
		stop
	}
}